http://FMPro.info  FileMaker Pro 関連総合ポータルサイト

IsValidEmail 関数

カテゴリー : テキスト処理
計算結果のデータタイプ : テキスト
対応FileMakerバージョン : 対応 7  対応 8  対応 8.5  対応 9  対応 10  対応 11  対応 12  対応 13  未対応 14  未対応 15
作者 : 社本修司 株式会社ジェネコム

概要

<メールアドレス>が妥当な場合に真「1」を返します。妥当ではない場合、偽「0」を返します。

構文

IsValidEmail ( メールアドレス ; オプション )

引数

引数名タイプ備考
メールアドレステキスト任意のテキストfoo @example.com
オプション数字0 か 1
1の場合、真偽のかわりに理由を返します。
1

別のウィンドウで、引数の値を変更してテストすることが出来ます

IsValidEmail ( "foo @example.com" ; 1 )

結果

アカウント(@の左側)に無効な文字列(" "スペース)が含まれています

/*==============================================================
  カスタム関数 IsValidEmail ( メールアドレス ; オプション )

<メールアドレス>が妥当な場合に真「1」を返します。妥当ではない場合、偽「0」を返します。
オプションに「1」を指定することで偽の場合にその理由を返し、真の場合はnull値を返します。
(オプション「0」の場合の結果は「1」か「0」)

# トップレベルドメインは2010年9月現在申請中・削除予定も含む <http://www.nic.ad.jp/ja/dom/types.html> 参照
# ドメイン名のルールは JPNIC の「ドメイン名のしくみ」を参照 <http://www.nic.ad.jp/ja/dom/system.html>
# ドメイン名のラベルは第6レベルまで判定
# ローカルパートで利用出来る文字列は RFC2822 3.2.4. Atom の atext による
# 日本語訳 <http://www.puni.net/~mimori/rfc/rfc2822.txt> 参照
#
# ()によるコメントや、""によるローカルパート表記、日本語ドメインを含む国際化ドメイン名は考慮していません
# .tokyo などの 新gTLD にはいまのところ対応していません

このカスタム関数を引用するに当たっては、必ずコメントも一緒に引用してください。
==============================================================*/


Let
(
    [
    ~addrSpec = Lower ( メールアドレス ) ;
    ~option = オプション ;

    ~tldList =
        "com¶net¶org¶edu¶gov¶mil¶int¶info¶biz¶name¶pro¶museum¶aero¶coop¶jobs¶travel¶mobi¶cat¶post¶tel¶xxx¶asia¶arpa¶ac¶ad¶ae¶af¶ag¶ai¶al¶am¶an¶ao¶aq¶ar¶as¶at¶au¶aw¶ax¶az¶ba¶bb¶bd¶be¶bf¶bg¶bh¶bi¶bj¶bl¶bm¶bn¶bo¶br¶bs¶bt¶bv¶bw¶by¶bz¶ca¶cc¶cd¶cf¶cg¶ch¶ci¶ck¶cl¶cm¶cn¶co¶cr¶cs¶cu¶cv¶cx¶cy¶cz¶de¶dj¶dk¶dm¶do¶dz¶ec¶ee¶eg¶eh¶er¶es¶et¶eu¶fi¶fj¶fk¶fm¶fo¶fr¶ga¶gb¶gd¶ge¶gf¶gg¶gh¶gi¶gl¶gm¶gn¶gp¶gq¶gr¶gs¶gt¶gu¶gw¶gy¶hk¶hm¶hn¶hr¶ht¶hu¶id¶ie¶il¶im¶in¶io¶iq¶ir¶is¶it¶je¶jm¶jo¶jp¶ke¶kg¶kh¶ki¶km¶kn¶kp¶kr¶kw¶ky¶kz¶la¶lb¶lc¶li¶lk¶lr¶ls¶lt¶lu¶lv¶ly¶ma¶mc¶md¶me¶mf¶mg¶mh¶mk¶ml¶mm¶mn¶mo¶mp¶mq¶mr¶ms¶mt¶mu¶mv¶mw¶mx¶my¶mz¶na¶nc¶ne¶nf¶ng¶ni¶nl¶no¶np¶nr¶nu¶nz¶om¶pa¶pe¶pf¶pg¶ph¶pk¶pl¶pm¶pn¶pr¶ps¶pt¶pw¶py¶qa¶re¶ro¶rs¶ru¶rw¶sa¶sb¶sc¶sd¶se¶sg¶sh¶si¶sj¶sk¶sl¶sm¶sn¶so¶sr¶st¶sv¶sy¶sz¶tc¶td¶tf¶tg¶th¶tj¶tk¶tl¶tm¶tn¶to¶tp¶tr¶tt¶tv¶tw¶tz¶ua¶ug¶uk¶um¶us¶uy¶uz¶va¶vc¶ve¶vg¶vi¶vn¶vu¶wf¶ws¶ye¶yt¶yu¶za¶zm¶zw¶su¶" ;
        // トップレベルドメインのリスト <http://www.nic.ad.jp/ja/dom/types.html> 参照
        // su 旧ソビエト連邦 wikipediaによると未だに使われているらしい
    ~jpList = "ac¶co¶go¶or¶ad¶ne¶gr¶ed¶lg¶" ;     // 属性型(組織種別型)JP ドメイン名の属性リスト

    ~pSeparator = Position ( ~addrSpec ; "@" ; 1 ; PatternCount ( ~addrSpec ; "@" ) ) ;     // @が2回以上書かれた場合を考慮して最後の@をドメインとの区切りとする
    ~localPart = Left ( ~addrSpec ; ~pSeparator - 1 ) ;     // ローカルパート(アカウント名)
    ~domain = Right ( ~addrSpec ; Length ( ~addrSpec ) - ~pSeparator ) ;    // ドメイン名

    ~pLastDot = Position ( ~domain ; "." ; 1 ; PatternCount ( ~domain ; "." ) ) ;
    ~pLavel2Dot = Position ( ~domain ; "." ; 1 ; PatternCount ( ~domain ; "." ) - 1 ) ;
    ~pLavel3Dot = Position ( ~domain ; "." ; 1 ; PatternCount ( ~domain ; "." ) - 2 ) ;
    ~pLavel4Dot = Position ( ~domain ; "." ; 1 ; PatternCount ( ~domain ; "." ) - 3 ) ;
    ~pLavel5Dot = Position ( ~domain ; "." ; 1 ; PatternCount ( ~domain ; "." ) - 4 ) ;
    ~pLavel6Dot = Position ( ~domain ; "." ; 1 ; PatternCount ( ~domain ; "." ) - 5 ) ;

    ~topLevelDomain = Middle ( ~domain ; ~pLastDot + 1 ; Length ( ~domain ) - ~pLastDot ) ;     // トップレベルドメイン
    ~lavel2 = Middle ( ~domain ; ~pLavel2Dot + 1 ; ~pLastDot - ~pLavel2Dot - 1 ) ;     // 第2レベルドメイン
    ~lavel3 = Middle ( ~domain ; ~pLavel3Dot + 1 ; ~pLavel2Dot - ~pLavel3Dot - 1 ) ;     // 第3レベルドメイン
    ~lavel4 = Middle ( ~domain ; ~pLavel4Dot + 1 ; ~pLavel3Dot - ~pLavel4Dot - 1 ) ;     // 第4レベルドメイン
    ~lavel5 = Middle ( ~domain ; ~pLavel5Dot + 1 ; ~pLavel4Dot - ~pLavel5Dot - 1 ) ;     // 第5レベルドメイン
    ~lavel6 = Middle ( ~domain ; ~pLavel6Dot + 1 ; ~pLavel5Dot - ~pLavel6Dot - 1 ) ;     // 第6レベルドメイン

    ~docomo = Exact ( ~domain ; "docomo.ne.jp" ) or Exact ( ~domain ; "ezweb.ne.jp" ) or PatternCount ( ~domain ; ".ezweb.ne.jp" ) ;     // 携帯アドレス特別ルール判定用
    ~jp = Exact ( ~topLevelDomain ; "jp" ) and Length ( ~lavel2 ) ≤ 2 ;     // 属性型(組織種別型)JP ドメイン判定用
    ~jo = Exact ( ~topLevelDomain ; "jo" ) and Length ( ~lavel2 ) ≤ 2 ;     // JP のtypo対策(ヨルダン Jordan ドメインの属性は3文字)

    ~filtereLocalPart =
       Filter (
            ~localPart ;
            "abcdefghijklmnopqrstuvwxyz" &
            "ABCDEFGHIJKLMNOPQRSTUVWXYZ" &
            "0123456789" &
            "!#$%&'*+-/=?^_`{|}~" &
            "."
        ) ;
    ~filtereDomain =
       Filter (
            ~domain ;
            "abcdefghijklmnopqrstuvwxyz" &
            "ABCDEFGHIJKLMNOPQRSTUVWXYZ" &
            "0123456789-."
        ) ;

    ~result =
       Case (
           IsEmpty ( ~addrSpec ) ;
                "メールアドレスが空です" ;

           PatternCount ( ~addrSpec ; "@" ) = 0 or
           IsEmpty ( ~domain ) ;
                "ドメイン(@の右側)が空です" ;
           PatternCount ( ~domain ; "." ) = 0 ;
                "無効なドメイン(@の右側)です" ;
           Length ( ~domain ) > 255 ;
                "ドメイン(@の右側)が長すぎます" ;     // ドメイン名全体の長さは255文字以下
           Length ( ~lavel2 ) > 63 or
           Length ( ~lavel3 ) > 63 or
           Length ( ~lavel4 ) > 63 or
           Length ( ~lavel5 ) > 63 or
           Length ( ~lavel6 ) > 63 ;
                "無効なドメイン(@の右側)です" ; // 各ラベルの長さは63文字以下
           Left ( ~domain ; 1 ) = "-" ;
                "ドメインの最初を\"-\"(ハイフン)にすることは出来ません" ;
           Left ( ~lavel2 ; 1 ) = "-" or Right ( ~lavel2 ; 1 ) = "-" or
           Left ( ~lavel3 ; 1 ) = "-" or Right ( ~lavel3 ; 1 ) = "-" or
           Left ( ~lavel4 ; 1 ) = "-" or Right ( ~lavel4 ; 1 ) = "-" or
           Left ( ~lavel5 ; 1 ) = "-" or Right ( ~lavel5 ; 1 ) = "-" or
           Left ( ~lavel6 ; 1 ) = "-" or Right ( ~lavel6 ; 1 ) = "-" ;
                "無効なドメインです(\".\"(ドット)の直前または直後を\"-\"(ハイフン)にすることは出来ません)" ;     // ラベルの先頭と最後にハイフンは使用できない
            not Exact ( ~domain ; ~filtereDomain ) and PatternCount ( ~domain ; "¶" ) ;
                "ドメイン(@の右側)に無効な文字列(改行)が含まれています" ;
            not Exact ( ~domain ; ~filtereDomain ) and ( PatternCount ( ~domain ; " " ) or PatternCount ( ~domain ; " " ) ) ;
                "ドメイン(@の右側)に無効な文字列(\" \"スペース)が含まれています" ;
            not Exact ( ~domain ; ~filtereDomain ) ;
                "ドメイン(@の右側)に無効な文字列が含まれています" ;
           Left ( ~domain ; 1 ) = "." ;
                "ドメイン(@の右側)の最初を\".\"(ドット)にすることは出来ません" ;
           Right ( ~domain ; 1 ) = "." ;
                "ドメイン(@の右側)の最後を\".\"(ドット)にすることは出来ません" ;
           PatternCount ( ~domain ; ".." ) ≥ 1 ;
                "ドメイン(@の右側)に\"..\"を含める(ドットを二つ続ける)ことは出来ません" ;
           IsEmpty ( FilterValues ( ~topLevelDomain ; ~tldList ) ) ;
                "トップレベルドメイン(最後の\".jp\"など)が無効です" ;
            ~jp and IsEmpty ( FilterValues ( ~lavel2 ; ~jpList ) ) ;
                "ドメインの属性(\".co\"や\".ne\"など)が無効です" ;     // 属性型(組織種別型)JP ドメインの場合は属性もチェック
            ~jo and not IsEmpty ( FilterValues ( ~lavel2 ; ~jpList ) ) ;
                "ヨルダン(Jordan)ドメインの属性は \".com, .org, .edu, .mil, .net, .gov\" のいずれかです" ;

            not Exact ( ~localPart ; ~filtereLocalPart ) and ( PatternCount ( ~localPart ; " " ) or PatternCount ( ~localPart ; " " ) ) ;
                "アカウント(@の左側)に無効な文字列(\" \"スペース)が含まれています" ;
            not Exact ( ~localPart ; ~filtereLocalPart ) ;
                "アカウント(@の左側)に無効な文字列が含まれています" ;
           Left ( ~localPart ; 1 ) = "." ;
                "アカウントの最初を\".\"(ドット)にすることは出来ません" ;

            not ~docomo and Right ( ~localPart ; 1 ) = "." ;
                "アカウント(@の左側)の最後を\".\"(ドット)にすることは出来ません" ;
            not ~docomo and PatternCount ( ~localPart ; ".." ) ≥ 1 ;
                "アカウント(@の左側)に\"..\"を含める(ドットを二つ続ける)ことは出来ません" ;
                // docomo.ne.jp ないしは ezweb.ne.jp の場合、.の扱いが RFC2822 で認められていない使い方ができるため
        )
    ] ;

   Case (
        ~option ;
            ~result ;
           IsEmpty ( ~result )
    )

)
// ©2006-2010,SHAMOTO Syuji <http://www.FMPro.jp>

エンコードは Unicode (UTF-8)、改行タイプは LF (Unix) 形式のテキストとして保存します。
テキストエディタで正常に開かない場合は、エンコードを指定してファイルを開くようにしてください。

詳細説明

<メールアドレス>が妥当な場合に真「1」を返します。妥当ではない場合、偽「0」を返します。
オプションに「1」を指定することで偽の場合にその理由をかえし、真の場合はnull値を返します。
(オプション「0」の場合の結果は「1」か「0」)
()によるコメントや、""によるローカルパート表記、日本語ドメインを含む国際化ドメイン名は考慮していません。

この関数が使用する他のカスタム関数

この関数を使用する他のカスタム関数

注意:ここで紹介されているカスタム関数をご自分のシステムに組み込んだ場合に発生した問題についてはFMPro.infoは責任を負いません。

Copyright © 2004-2009 FMPro.info All Rights Reserved.