TextExtraction 関数

/*==============================================================

  カスタム関数    TextExtraction ( テキスト ; 開始テキスト ; 開始テキスト回数 ; 終了テキスト ; 終了テキスト回数 )

  指定したテキストから任意のテキスト間の文字列を返します。
  <テキスト>の中から指定された<開始テキスト回数>番目の<開始テキスト>の次の文字列から
  その開始テキスト以降に現れる<終了テキスト回数>番目の<終了テキスト>までの文字列を返します。

=============================================================*/

Let (
    [
    TEXT = テキスト;
    STARTINGTEXT = 開始テキスト ;
    NUMBEROFSTARTINGTEXTS = 開始テキスト回数 ;  
    ENDINGTEXT = 終了テキスト ;
    // 終了テキストが開始テキストに含まれている場合その数だけをプラス
    NUMBEROFENDINGTEXTS = 終了テキスト回数  + PatternCount ( STARTINGTEXT ; 終了テキスト ) ;

    //----------------------------------------------------------------------
    // 抽出するテキストの先頭文字位置
    //----------------------------------------------------------------------
    SP = Position ( TEXT ; STARTINGTEXT ; 1 ; NUMBEROFSTARTINGTEXTS ) + Length ( STARTINGTEXT ) ;

    //----------------------------------------------------------------------
    // 終了テキストの文字位置
    //----------------------------------------------------------------------
    EP = Position ( TEXT ; ENDINGTEXT ; Position ( TEXT; STARTINGTEXT; 1; NUMBEROFSTARTINGTEXTS ) ; NUMBEROFENDINGTEXTS ) ;

    //----------------------------------------------------------------------
    // 抽出するテキストの文字数
    //----------------------------------------------------------------------
    NC = EP - SP

    ] ;

   Case (

        // Text中にstartingTextがNumberOfStartingTexts回以上存在するか
        // StartingText以降のText中にEndingTextが終了テキスト回数以上存在するか
        // （NumberOfEndingTexts回ではなく終了テキスト回数）

       PatternCount ( TEXT ; STARTINGTEXT ) ≥ NUMBEROFSTARTINGTEXTS
        and PatternCount ( Middle ( TEXT ; SP ; Length ( TEXT ) - SP + 1 ) ; ENDINGTEXT ) ≥ 終了テキスト回数 ;
        
           Middle ( TEXT ; SP ; NC )
    )
)

// ©2004,SHAMOTO Syuji <http://www.FMPro.jp>